bon, je devais poster les scripts de migration mais je n' ai pas eu le temps d' épurer ceux ci des données personnelles, il faudra donc attendre un peu plus longtemps.

En attendant, voila un script fort utile pour paramétrer le client de messagerie que l' on veut pour les liens mailto (vous savez les 'contactez-nous' sur les pages web...) et le SendToMail (click droit, envoyer vers, destinataire).

Cela permet, de rediriger par exemple, ces deux fonctions vers un serveur OWA...utile par exemple pour certains environnements banalisés, qui souhaitent empêcher l' exécution d' Outlook tout en gardant la majorité des fonctions utilisateur...

Le script ci dessous ouvre une fenêtre demandant le FQDN de votre serveur OWA, et le renseigne dans HKLM comme pointeur potentiel pour ces fonctions. Il ne modifie les fonctions QUE POUR LE CURRENT USER, l' utilisateur ayant exécuté ce script. Il n' impacte donc pas l' environnement standard du poste, hormis l' ajout du pointeur.

Libre à vous de le modifier par exemple pour lancer Windows Mail, ou Thunderbird... à chacun ses goûts et ses défis :)

 

'-------------------------------------------------------
'
'Script de paramétrage OWA en fonction MAilto:()
'SU 2008 - PJ 09/08/08
'
'-------------------------------------------------------

' Initialize error handling
Option Explicit
On Error Resume Next

' Declare variables
Dim objWSHShell ' As WScript.Shell
Dim strInput ' As String

' Ask for FQDN to Exchange Server
strInput = InputBox("Saisissez le FQDN du serveur Exchange. Si vous utilisez SSL pensez à l'URL en https: (exemple: <https://myserver.mydomain.com>) ")

' Check if server FQDN has been supplied
If Trim(strInput) <> "" Then

' Put registry settings to make OWA a mail client one can choose in IE
Set objWSHShell = WScript.CreateObject("WScript.Shell")
With objWSHShell
'adds Microsoft Outlook Web access as a Mail Handler on the system.
.RegWrite "HKLM\SOFTWARE\Clients\Mail\Outlook Web Access\", "Microsoft Outlook Web Access", "REG_SZ"
.RegWrite "HKLM\SOFTWARE\Clients\Mail\Outlook Web Access\Protocols\mailto\", "URL:MailTo Protocol", "REG_SZ"
.RegWrite "HKLM\SOFTWARE\Clients\Mail\Outlook Web Access\Protocols\mailto\URL Protocol", "", "REG_SZ"
.RegWrite "HKLM\SOFTWARE\Clients\Mail\Outlook Web Access\Protocols\mailto\EditFlags", &H00000002, "REG_BINARY"
.RegWrite "HKLM\SOFTWARE\Clients\Mail\Outlook Web Access\Protocols\mailto\DefaultIcon\", "%ProgramFiles%\Outlook Express\msimn.exe,-2", "REG_EXPAND_SZ"
.RegWrite "HKLM\SOFTWARE\Clients\Mail\Outlook Web Access\shell\open\command\", """%ProgramFiles%\Internet Explorer\iexplore.exe"" " & strInput , "REG_EXPAND_SZ"
'sets the path and Variables to open up and address a message inside of OWA - used by Send to Mail selection
.RegWrite "HKCU\SOFTWARE\Clients\Mail\Outlook Web Access\Protocols\mailto\shell\open\command\", """%ProgramFiles%\Internet Explorer\iexplore.exe"" " & strInput , "REG_EXPAND_SZ"
'sets the path and Variables to open up and address a message inside of OWA - used by mailto: links
.RegWrite "HKCU\SOFTWARE\Classes\mailto\shell\open\command\", """%ProgramFiles%\Internet Explorer\iexplore.exe"" " & strInput , "REG_EXPAND_SZ"
'changes the internet program setting for mail to defautl to OWA
.RegWrite "HKCU\SOFTWARE\Clients\Mail\","Outlook Web Access", "REG_SZ"
End With

' Tidy up
Set objWSHShell = Nothing
Else
WScript.Echo "Veuillez saisir un nom FQDN valide pour le frontal OWA"
End If

' Tidy up
Set objWSHShell = Nothing

' Say good bye
WScript.Echo "Paramétrage de la fonction MailTo terminé."

'----------------------------------------------------------

Ce script a été trouvé sur le net et modifié par mes soins, il peut bien sur être remodifié par les vôtres...après tout ce n' est que du VBScript :)

Pierre.